gcp_security_command_center_service_disabled

 rule gcp_security_command_center_service_disabled {

  meta:
    author = "Google Cloud Security"
    description = "Detect when GCP Security Command Center services are disabled."
    rule_id = "mr_0d065dd8-4489-434a-bb6e-066537318484"
    rule_name = "GCP Security Command Center Service Disabled"
    mitre_attack_tactic = "Defense Evasion"
    mitre_attack_technique = "Impair Defenses"
    mitre_attack_url = "https://attack.mitre.org/techniques/T1562/"
    mitre_attack_version = "v14.1"
    type = "Alert"
    data_source = "GCP Cloud Audit"
    platform = "GCP"
    severity = "High"
    priority = "High"

  events:
    $gcp.metadata.event_type = "RESOURCE_WRITTEN"
    $gcp.metadata.log_type = "GCP_CLOUDAUDIT"
    $gcp.metadata.product_event_type = /google.cloud.securitycenter.settings.*.Settings.Update/
    $gcp.security_result.action = "ALLOW"
    $gcp.target.application = "securitycenter.googleapis.com"
    $gcp.target.resource.attribute.labels["service_enablement_state"] = "DISABLED"

  outcome:
    $risk_score = max(75)
    $mitre_attack_tactic = "Defense Evasion"
    $mitre_attack_technique = "Impair Defenses"
    $mitre_attack_technique_id = "T1562"
    $event_count = count_distinct($gcp.metadata.id)
    $network_http_user_agent = $gcp.network.http.user_agent
    $principal_ip = array_distinct($gcp.principal.ip)
    $principal_ip_country = array_distinct($gcp.principal.ip_geo_artifact.location.country_or_region)
    $principal_ip_state = array_distinct($gcp.principal.ip_geo_artifact.location.state)
    $principal_user_id = $gcp.principal.user.userid
    $principal_user_display_name = $gcp.principal.user.user_display_name
    $target_resource_name = $gcp.target.resource.name

  condition:
    $gcp
}