google_workspace_external_user_added_to_group

rule google_workspace_external_user_added_to_group {

  meta:
    author = "Google Cloud Security"
    description = "Identifies when an external user account is added to a group in Google Workspace. Security teams can monitor for unexpected user accounts being added to Google Workspace groups to prevent unauthorized access to data."
    rule_id = "mr_c64af222-e029-4add-ac9c-b9285c5eb135"
    rule_name = "Google Workspace External User Added To Group"
    mitre_attack_tactic = "Initial Access"
    mitre_attack_technique = "Valid Accounts: Cloud Accounts"
    mitre_attack_url = "https://attack.mitre.org/techniques/T1078/004/"
    mitre_attack_version = "v13.1"
    type = "Alert"
    data_source = "Workspace Activity"
    severity = "Medium"
    priority = "Medium"

  events:
    $ws.metadata.vendor_name = "Google Workspace"
    $ws.metadata.product_name = "admin"
    $ws.metadata.event_type = "GROUP_MODIFICATION"
    $ws.metadata.product_event_type = "ADD_GROUP_MEMBER"

    $group_domain = re.capture($ws.target.group.email_addresses, `@[a-zA-Z0-9\.]*`)
    $user_domain = re.capture($ws.src.user.email_addresses, `@[a-zA-Z0-9\.]*`)

    $group_domain != $user_domain

  outcome:
    $risk_score = max(35)
    $mitre_attack_tactic = "Initial Access"
    $mitre_attack_technique = "Valid Accounts: Cloud Accounts"
    $mitre_attack_technique_id = "T1078.004"
    $event_count = count_distinct($ws.metadata.id)
    $target_group_domain = $group_domain
    $src_user_domain = $user_domain
    $target_group_emails = array_distinct($ws.target.group.email_addresses)
    $src_user_emails = array_distinct($ws.src.user.email_addresses)
    $principal_ip = array_distinct($ws.principal.ip)
    $principal_country = array_distinct($ws.principal.ip_geo_artifact.location.country_or_region)
    $principal_state = array_distinct($ws.principal.ip_geo_artifact.location.state)
    $principal_user_emails = array_distinct($ws.principal.user.email_addresses)
    $principal_user_id = $ws.principal.user.userid

  condition:
    $ws
}