sap_security_audit_log_configuration_change

rule sap_security_audit_log_configuration_change {

  meta:
    author = "Google Cloud Security"
    description = "Detects changes to the SAP Security Audit Log configuration. Monitoring message codes AUE, AUF, AUI, AUJ, FU0, and E05."
    severity = "High"
    tactic = "TA0005"
    technique = "T1562"

  events:
    $e.metadata.log_type = "SAP_SECURITY_AUDIT"

    $e.additional.fields["msg_1"] = /^AUE$|^AUF$|^AUI$|^AUJ$|^FU0$|^E05$/

    $user = $e.principal.user.userid
    $sid = $e.target.application

    not $user in %sap_admin_users.user

  match:
    $user, $sid over 1h

  outcome:
    $risk_score = 75
    $target_sid = array_distinct($sid)
    $description = array_distinct($e.metadata.description)
    $terminal = array_distinct($e.principal.hostname)
    $message_ids = array_distinct($e.additional.fields["msg_1"])
    $t_code = array_distinct($e.security_result.detection_fields["slgtc_1"])
    $TXSUBCLSID = array_distinct($e.security_result.summary)
    $system = array_distinct($e.target.application)
    $instance = array_distinct($e.target.resource.name)


  condition:
    $e
}