hash_prevalence

rule hash_prevalence {

  meta:
    author = "Google Cloud Security"
    description = "Correlate process events with hashes that have a low rolling max over the past 10 days"
    rule_id = "mr_abaa155b-f4ce-4fb2-b525-3eed59bca6d1"
    rule_name = "Hash Prevalence"
    type = "alert"
    tags = "prevalence"
    data_source = "crowdstrike, sentinelone, microsoft sysmon, microsoft defender atp"
    severity = "Low"
    priority = "Low"

  events:
    $process.metadata.event_type = "PROCESS_LAUNCH"
    $process.target.process.file.sha256 = $sha256

    $prevalence.graph.metadata.entity_type = "FILE"
    $prevalence.graph.metadata.source_type = "DERIVED_CONTEXT"
    $prevalence.graph.entity.file.prevalence.day_count = 10
    $prevalence.graph.entity.file.prevalence.rolling_max <= 3
    $prevalence.graph.entity.file.prevalence.rolling_max > 0
    $prevalence.graph.entity.file.sha256 = $sha256

  match:
    $sha256 over 5m

  outcome:
    $risk_score = 35
    $event_count = count_distinct($process.metadata.id)
    // added to populate alert graph with additional context
    $principal_hostname = array_distinct($process.principal.hostname)
    $principal_process_pid = array_distinct($process.principal.process.pid)
    $principal_process_command_line = array_distinct($process.principal.process.command_line)
    $principal_process_file_sha256 = array_distinct($process.principal.process.file.sha256)
    $principal_process_file_full_path = array_distinct($process.principal.process.file.full_path)
    $principal_process_product_specific_process_id = array_distinct($process.principal.process.product_specific_process_id)
    $principal_process_parent_process_product_specific_process_id = array_distinct($process.principal.process.parent_process.product_specific_process_id)
    $target_process_pid = array_distinct($process.target.process.pid)
    $target_process_command_line = array_distinct($process.target.process.command_line)
    // Commented out process.target.process.file.sha256 because it is already represented in graph as match variable. If match changes, can uncomment to add to results
    //$target_process_file_sha256 = array_distinct($process.target.process.file.sha256)
    $target_process_file_full_path = array_distinct($process.target.process.file.full_path)
    $target_process_product_specific_process_id = array_distinct($process.target.process.product_specific_process_id)
    $principal_user_userid = array_distinct($process.principal.user.userid)

  condition:
    $process and $prevalence
}