recon_suspicious_commands_cisa_report
Description
Detects suspicious commands as identified in CISA Living off the Land pdf. Alone they may be normal but in concert, they may be worth looking into
Query · yara_l
events:
$process.metadata.event_type = "PROCESS_LAUNCH"
$process.principal.hostname = $hostname
$process.target.process.command_line = $command_line
// cisa report referenced cmd /c in their report throughout, can filter this in/out for tuning as needed
// other wmic switches like /user and /password, these have been excluded to focus on the commands being issued since local access does not require these
(
re.regex($process.target.process.command_line, `(^|[\\/])7z\b.*?\ba\b.*?\b-p.*?\bc:\\windows\\temp\\.*\.7z`) nocase or
re.regex($process.target.process.command_line, `(^|[\\/])pcwrun\.exe\b.*?\bc:\\Users\\Administrator\\Desktop\\Win\.exe`) nocase or
re.regex($process.target.process.command_line, `(^|[\\/])(cmd(\.exe)?|cmdbak)\b.*?[/c]\b.*?\bping\b.*?\b-n\b.*?\b1\b.*?\b127\.0\.0\.1\b.*?\bc:\\Windows\\temp\\(putty|tmp)\.log`) nocase or
// The following line could be swapped for the previous line for a looser match. It was observed during testing that a c2 running powershell logged putty.log as a file creation but not in the command line process event
//re.regex($process.target.process.command_line, `(^|[\\/])ping\b.*?\b-n\b.*?\b1\b.*?\b127\.0\.0\.1`) nocase or
re.regex($process.target.process.command_line, `(^|[\\/])(cmd(\.exe)?|cmdbak)\b.*?[/c]\b.*?\bdir\b.*?\b127\.0\.0\.1\\c\$.*?/od`) nocase or
re.regex($process.target.process.command_line, `(^|[\\/])ping\b.*?\b-a\b.*?\b-n\b.*?\b1\b`) nocase or
re.regex($process.target.process.command_line, `(^|[\\/])wmic\b.*?\bprocess\b.*?\bcall\b.*?\bcreate\b.*?\bnet\b.*?\bstop\b.*?\bC:\\Windows\\Temp\\tmp\.log"`) nocase or
re.regex($process.target.process.command_line, `\\ADMIN\$\\__.*2>&1`) nocase or
//The following line could be swapped for the previous line for a looser match, but potentially noisier
//re.regex($process.target.process.command_line, `\\ADMIN\$\\__`) nocase or
re.regex($process.target.process.command_line, `(^|[\\/])net\b.*?\buse\b.*?\b127\.0\.0\.1\\ipc\$.*?/y.*?/d`) nocase or
re.regex($process.target.process.command_line, `(^|[\\/])powershell\b.*?\bstart-process\b.*?\b-filepath\b.*?\bc:\\windows\\temp\\.*\.bat\b.*?\b-windowstyle\b.*?\bHidden`) nocase or
re.regex($process.target.process.command_line, `(^|[\\/])rar\.exe\b.*?\ba\b.*?\bc:\\Windows\\temp\\.*?D:\\`) nocase or
re.regex($process.target.process.command_line, `(^|[\\/])wmic\b.*?\b(cmd(\.exe)?|cmdbak)\b.*?[/c]\b.*?\bwhoami`) nocase or
re.regex($process.target.process.command_line, `(^|[\\/])xcopy\b.*?\bc:\\windows\\temp\\hp\b.*?\bd:\\`) nocase
)
match:
$hostname over 15m
outcome:
$risk_score = 35
$event_count = count_distinct($process.metadata.id)
$unique_command_line_threshold = 5
// added to populate alert graph with additional context
// Commented out principal.hostname because it is already represented in graph as match variable. If match changes, can uncomment to add to results
//$principal_hostname = array_distinct($process.principal.hostname)
$principal_process_pid = array_distinct($process.principal.process.pid)
$principal_process_command_line = array_distinct($process.principal.process.command_line)
$principal_process_file_sha256 = array_distinct($process.principal.process.file.sha256)
$principal_process_file_full_path = array_distinct($process.principal.process.file.full_path)
$principal_process_product_specific_process_id = array_distinct($process.principal.process.product_specific_process_id)
$principal_process_parent_process_product_specific_process_id = array_distinct($process.principal.process.parent_process.product_specific_process_id)
$target_process_pid = array_distinct($process.target.process.pid)
$target_process_command_line = array_distinct($process.target.process.command_line)
$target_process_file_sha256 = array_distinct($process.target.process.file.sha256)
$target_process_file_full_path = array_distinct($process.target.process.file.full_path)
$target_process_product_specific_process_id = array_distinct($process.target.process.product_specific_process_id)
$principal_user_userid = array_distinct($process.principal.user.userid)
condition:
// modify the condition value for command line to throttle how many of these unique commands can be seen until the rule is triggered
$process and #command_line > 5