aws_ec2_high_number_of_api_calls

rule aws_ec2_high_number_of_api_calls {

  meta:
    author = "Google Cloud Security"
    description = "Detect when an EC2 instance makes high number of API calls."
    rule_id = "mr_d19289e1-4385-4757-bf54-0f61e7a789a4"
    rule_name = "AWS EC2 High Number Of API Calls"
    mitre_attack_tactic = "Discovery"
    mitre_attack_technique = "Cloud Infrastructure Discovery"
    mitre_attack_url = "https://attack.mitre.org/techniques/T1580/"
    mitre_attack_version = "v13.1"
    type = "Alert"
    data_source = "AWS CloudTrail"
    platform = "AWS"
    severity = "Low"
    priority = "Low"

  events:
    $api.metadata.vendor_name = "AMAZON"
    $api.metadata.product_name = "AWS CloudTrail"
    $api.principal.resource.type = "AssumedRole"
    $api.principal.user.userid = /\/i-.*$/ //regex to be improved
    re.capture($api.principal.user.userid, ":assumed-role/.*/(.*)$") = $instanceId
    $api.principal.ip = $ip

  match:
    $ip, $instanceId over 5m

  outcome:
    $risk_score = max(35)
    $mitre_attack_tactic = "Discovery"
    $mitre_attack_technique = "Cloud Infrastructure Discovery"
    $mitre_attack_technique_id = "T1580"
    $event_count = count_distinct($api.metadata.id)
    $network_http_user_agent = array_distinct($api.network.http.user_agent)
    $principal_ip = array_distinct($api.principal.ip)
    $principal_ip_country = array_distinct($api.principal.ip_geo_artifact.location.country_or_region)
    $principal_ip_state = array_distinct($api.principal.ip_geo_artifact.location.state)
    $principal_user_display_name = array_distinct($api.principal.user.user_display_name)
    $dc_product_event_type = count_distinct($api.metadata.product_event_type)
    $aws_region = array_distinct($api.principal.location.name)
    $target_resource_name = array_distinct($api.target.resource.name)
    $target_resource_product_object_id = array_distinct($api.target.resource.product_object_id)

  condition:
    $api and $dc_product_event_type > 7
}