sap_restricted_transaction_started


Description

A user started a transaction code on the restricted transaction list

Query · yara_l

events:
    $e.metadata.log_type = "SAP_SECURITY_AUDIT"

    $e.additional.fields["msg_1"] = /^(AU3|AU4)$/
    $tcode = $e.additional.fields["param1_1"]
    $tcode in %sap_sensitive_transactions.transaction_code

    $user = $e.principal.user.userid
    $sid  = $e.target.application

    not $user in %sap_excluded_users.userid

  match:
    $user, $sid over 75m

  outcome:
    $risk_score = 75
    $executed_tcode = array_distinct($tcode)
    $abap_program = array_distinct($e.principal.process.file.names)
    $terminal_ip = array_distinct($e.principal.ip)
    $sap_client = array_distinct($e.target.resource.attribute.labels["slgmand_1"])
    $log_description = array_distinct($e.metadata.description)
    $event_count = count_distinct($e.metadata.id)

  condition:
    $e
Raw source sap_restricted_transaction_started · YARA-L
Esc
Published by chronicle/detection-rules ↗, licensed under Apache 2.0 ↗. Reproduced here unmodified.
rule sap_restricted_transaction_started {

  meta:
    author = "Google Cloud Security"
    description = "A user started a transaction code on the restricted transaction list"
    severity = "High"
    tactic = "TA0009"
    technique = "T1005"

  events:
    $e.metadata.log_type = "SAP_SECURITY_AUDIT"

    $e.additional.fields["msg_1"] = /^(AU3|AU4)$/
    $tcode = $e.additional.fields["param1_1"]
    $tcode in %sap_sensitive_transactions.transaction_code

    $user = $e.principal.user.userid
    $sid  = $e.target.application

    not $user in %sap_excluded_users.userid

  match:
    $user, $sid over 75m

  outcome:
    $risk_score = 75
    $executed_tcode = array_distinct($tcode)
    $abap_program = array_distinct($e.principal.process.file.names)
    $terminal_ip = array_distinct($e.principal.ip)
    $sap_client = array_distinct($e.target.resource.attribute.labels["slgmand_1"])
    $log_description = array_distinct($e.metadata.description)
    $event_count = count_distinct($e.metadata.id)

  condition:
    $e
}

Detection rules belong to the projects that publish them and remain under their own licenses. This site indexes and links to them; it claims no rights in them.