sap_user_master_record_modified


Description

Detects the modification of a user's master record via an administrative action within SAP, which may indicate unauthorized account manipulation or privilege escalation.

Query · yara_l

events:
    $e.metadata.vendor_name = "SAP"
    $e.metadata.log_type = "SAP_SECURITY_AUDIT"
    // SAP Message ID 'AUD' corresponds to "User master record modified"
    $e.additional.fields["msg_1"] = "AUD"
    $user = $e.principal.user.userid
    $sid  = $e.target.application
    $user != ""

  match:
    $user, $sid over 1h

  outcome:
    $risk_score       = 65
    $event_count      = count_distinct($e.metadata.id)
    $source_user      = array_distinct($user)
    $target_sid       = array_distinct($sid)
    $modified_user    = array_distinct($e.additional.fields["param1_1"])
    $terminal_ip      = array_distinct($e.principal.ip)
    $terminal_name    = array_distinct($e.principal.hostname)
    $sap_client       = array_distinct($e.target.resource.attribute.labels["slgmand_1"])
    $transaction_code = array_distinct($e.security_result.detection_fields["slgtc_1"])
    $abap_program     = array_distinct($e.principal.process.file.names)
    $log_description  = array_distinct($e.metadata.description)
    $event_severity   = array_distinct($e.security_result.severity)

  condition:
    $e
Raw source sap_user_master_record_modified · YARA-L
Esc
Published by chronicle/detection-rules ↗, licensed under Apache 2.0 ↗. Reproduced here unmodified.
rule sap_user_master_record_modified {
  meta:
    author = "Google Cloud Security"
    name = "SAP - User Master Record Modified"
    description = "Detects the modification of a user's master record via an administrative action within SAP, which may indicate unauthorized account manipulation or privilege escalation."
    severity = "Medium"
    tactic = "TA0003"
    technique = "T1098"

  events:
    $e.metadata.vendor_name = "SAP"
    $e.metadata.log_type = "SAP_SECURITY_AUDIT"
    // SAP Message ID 'AUD' corresponds to "User master record modified"
    $e.additional.fields["msg_1"] = "AUD"
    $user = $e.principal.user.userid
    $sid  = $e.target.application
    $user != ""

  match:
    $user, $sid over 1h

  outcome:
    $risk_score       = 65
    $event_count      = count_distinct($e.metadata.id)
    $source_user      = array_distinct($user)
    $target_sid       = array_distinct($sid)
    $modified_user    = array_distinct($e.additional.fields["param1_1"])
    $terminal_ip      = array_distinct($e.principal.ip)
    $terminal_name    = array_distinct($e.principal.hostname)
    $sap_client       = array_distinct($e.target.resource.attribute.labels["slgmand_1"])
    $transaction_code = array_distinct($e.security_result.detection_fields["slgtc_1"])
    $abap_program     = array_distinct($e.principal.process.file.names)
    $log_description  = array_distinct($e.metadata.description)
    $event_severity   = array_distinct($e.security_result.severity)

  condition:
    $e
}

Detection rules belong to the projects that publish them and remain under their own licenses. This site indexes and links to them; it claims no rights in them.