gcp_multiple_hmac_keys_deleted

rule gcp_multiple_hmac_keys_deleted {

  meta:
    author = "Google Cloud Security"
    description = "Detect when multiple HMAC authentication keys are deleted from GCP Storage settings."
    rule_id = "mr_75b441f1-edde-4a33-bc12-06a92ccb9ba8"
    rule_name = "GCP Multiple HMAC Keys Deleted"
    mitre_attack_tactic = "Impact"
    mitre_attack_technique = "Account Access Removal"
    mitre_attack_url = "https://attack.mitre.org/techniques/T1531/"
    mitre_attack_version = "v14.1"
    type = "Alert"
    data_source = "GCP Cloud Audit"
    platform = "GCP"
    severity = "High"
    priority = "High"

  events:
    $gcp.metadata.event_type = "RESOURCE_DELETION"
    $gcp.metadata.log_type = "GCP_CLOUDAUDIT"
    $gcp.metadata.product_event_type = "storage.hmacKeys.delete"
    $gcp.target.application = "storage.googleapis.com"
    $gcp.target.user.userid = $user_id

  match:
    $user_id over 1h

  outcome:
    $risk_score = max(75)
    $mitre_attack_tactic = "Impact"
    $mitre_attack_technique = "Account Access Removal"
    $mitre_attack_technique_id = "T1531"
    $event_count = count_distinct($gcp.metadata.id)
    $network_http_user_agent = array_distinct($gcp.network.http.user_agent)
    $principal_ip = array_distinct($gcp.principal.ip)
    $principal_ip_country = array_distinct($gcp.principal.ip_geo_artifact.location.country_or_region)
    $principal_ip_state = array_distinct($gcp.principal.ip_geo_artifact.location.state)
    $principal_user_id = array_distinct($gcp.principal.user.userid)
    $principal_user_display_name = array_distinct($gcp.principal.user.user_display_name)
    $target_resource_name = array_distinct($gcp.target.resource.name)

  condition:
    #gcp >= 2
}