o365_group_modification_remove_member_success

rule o365_group_modification_remove_member_success {

  meta:
    author = "Google Cloud Security"
    description = "Detects when a user is removed from a group in Office 365."
    rule_id = "mr_fb6fe12b-737b-4d6c-a53f-3832343bc548"
    rule_name = "Hunt for Office 365 group modification remove member success"
    type = "hunt"
    platform = "azure"
    data_source = "o365"
    severity = "Low"
    priority = "Low"

  events:
    $group.metadata.event_type = "GROUP_MODIFICATION"
    $group.metadata.product_event_type = "Remove member from group."
    $group.metadata.product_name = "Office 365"
    $group.metadata.vendor_name = "Microsoft"
    $group.security_result.action = "ALLOW"
    $group.principal.user.userid = $user

  match:
    $user over 5m

  outcome:
    $risk_score = 35
    $event_count = count_distinct($group.metadata.id)
    $user_agent = array_distinct($group.network.http.user_agent)
    $security_summary = array_distinct($group.security_result.summary)
    $target_application = array_distinct($group.target.application)
    //Used in match section so excluding here
    //$principal_user_userid = array_distinct($app.principal.user.userid)
    $group_name = array_distinct($group.target.group.group_display_name)
    $group_guid = array_distinct($group.target.group.product_object_id)
    $user_removed = array_distinct($group.target.user.userid)
    $user_count = count_distinct($group.target.user.userid)

  condition:
    $group
}