sap_deprecated_function_module_invoked


Description

A user invoked a function module on the deprecated or unsafe module list

Query · yara_l

events:
    $e.metadata.log_type = "SAP_SECURITY_AUDIT"

    $e.additional.fields["msg_1"] = /^(AUK|AUL|BU4|DUI|DUJ|DUK|DUR|DUS|DUT|EUE|EUF|EUG|FU1)$/

    $user   = $e.principal.user.userid
    $system = $e.target.application

    $fm1 = re.capture($e.additional.fields["param1_1"], `^([^=]+)`)
    $fm2 = re.capture($e.additional.fields["param2_1"], `^([^=]+)`)
    $fm3 = re.capture($e.additional.fields["param3_1"], `^([^=]+)`)

    (
      $fm1 in %sap_obsolete_function_modules.function_module or
      $fm2 in %sap_obsolete_function_modules.function_module or
      $fm3 in %sap_obsolete_function_modules.function_module
    )

  match:
    $user, $system over 1h

  outcome:
    $risk_score = 80
    $module_param1 = array_distinct($fm1)
    $module_param2 = array_distinct($fm2)
    $module_param3 = array_distinct($fm3)
    $audit_message_id = array_distinct($e.additional.fields["msg_1"])
    $transaction_code = array_distinct($e.security_result.detection_fields["slgtc_1"])
    $abap_program = array_distinct($e.principal.process.file.names)
    $terminal_ip = array_distinct($e.principal.ip)
    $sap_client = array_distinct($e.target.resource.attribute.labels["slgmand_1"])
    $log_description = array_distinct($e.metadata.description)

  condition:
    $e
Raw source sap_deprecated_function_module_invoked · YARA-L
Esc
Published by chronicle/detection-rules ↗, licensed under Apache 2.0 ↗. Reproduced here unmodified.
rule sap_deprecated_function_module_invoked {

  meta:
    author = "Google Cloud Security"
    description = "A user invoked a function module on the deprecated or unsafe module list"
    severity = "High"
    tactic = "TA0002"
    technique = "T1129"

  events:
    $e.metadata.log_type = "SAP_SECURITY_AUDIT"

    $e.additional.fields["msg_1"] = /^(AUK|AUL|BU4|DUI|DUJ|DUK|DUR|DUS|DUT|EUE|EUF|EUG|FU1)$/

    $user   = $e.principal.user.userid
    $system = $e.target.application

    $fm1 = re.capture($e.additional.fields["param1_1"], `^([^=]+)`)
    $fm2 = re.capture($e.additional.fields["param2_1"], `^([^=]+)`)
    $fm3 = re.capture($e.additional.fields["param3_1"], `^([^=]+)`)

    (
      $fm1 in %sap_obsolete_function_modules.function_module or
      $fm2 in %sap_obsolete_function_modules.function_module or
      $fm3 in %sap_obsolete_function_modules.function_module
    )

  match:
    $user, $system over 1h

  outcome:
    $risk_score = 80
    $module_param1 = array_distinct($fm1)
    $module_param2 = array_distinct($fm2)
    $module_param3 = array_distinct($fm3)
    $audit_message_id = array_distinct($e.additional.fields["msg_1"])
    $transaction_code = array_distinct($e.security_result.detection_fields["slgtc_1"])
    $abap_program = array_distinct($e.principal.process.file.names)
    $terminal_ip = array_distinct($e.principal.ip)
    $sap_client = array_distinct($e.target.resource.attribute.labels["slgmand_1"])
    $log_description = array_distinct($e.metadata.description)

  condition:
    $e
}

Detection rules belong to the projects that publish them and remain under their own licenses. This site indexes and links to them; it claims no rights in them.