aws_iam_activity_by_s3_browser_utility

rule aws_iam_activity_by_s3_browser_utility {

  meta:
    author = "Google Cloud Security"
    description = "Detect AWS IAM activities associated with the S3 Browser utility."
    rule_id = "mr_003e618f-e099-4c72-a170-03d2e03836f9"
    rule_name = "AWS IAM Activity By S3 Browser Utility"
    reference = "https://permiso.io/blog/s/unmasking-guivil-new-cloud-threat-actor/"
    mitre_attack_tactic = "Persistence"
    mitre_attack_technique = "Account Manipulation"
    mitre_attack_url = "https://attack.mitre.org/techniques/T1098/"
    mitre_attack_version = "v13.1"
    type = "Alert"
    data_source = "AWS CloudTrail"
    platform = "AWS"
    severity = "High"
    priority = "High"

  events:
    $cloudtrail.metadata.vendor_name = "AMAZON"
    $cloudtrail.metadata.product_name = "AWS CloudTrail"
    $cloudtrail.target.application = "iam.amazonaws.com"
    (
      $cloudtrail.metadata.product_event_type = "CreateUser" or
      $cloudtrail.metadata.product_event_type = "CreateLoginProfile" or
      $cloudtrail.metadata.product_event_type = "CreateAccessKey" or
      $cloudtrail.metadata.product_event_type = "PutUserPolicy"
    )
    $cloudtrail.network.http.user_agent = /S3 Browser/
    $cloudtrail.security_result.action = "ALLOW"
    $cloudtrail.principal.ip = $ip

  match:
    $ip over 1h

  outcome:
    $risk_score = max(75)
    $mitre_attack_tactic = "Persistence"
    $mitre_attack_technique = "Account Manipulation"
    $mitre_attack_technique_id = "T1098"
    $event_count = count_distinct($cloudtrail.metadata.id)
    $network_http_user_agent = array_distinct($cloudtrail.network.http.user_agent)
    $principal_ip = array_distinct($cloudtrail.principal.ip)
    $principal_ip_country = array_distinct($cloudtrail.principal.ip_geo_artifact.location.country_or_region)
    $principal_ip_state = array_distinct($cloudtrail.principal.ip_geo_artifact.location.state)
    $target_user_display_name = array_distinct($cloudtrail.target.user.user_display_name)
    $recipient_aws_account_id = array_distinct($cloudtrail.additional.fields["recipientAccountId"])
    $aws_region = array_distinct($cloudtrail.principal.location.name)
    $target_resource_name = array_distinct($cloudtrail.target.resource.name)
    $target_resource_product_object_id = array_distinct($cloudtrail.target.resource.product_object_id)

  condition:
    $cloudtrail
}