Windows_VulnDriver_Biostar_881dc820

rule Windows_VulnDriver_Biostar_881dc820 {
    meta:
        author = "Elastic Security"
        id = "881dc820-9a0e-4b90-bae9-234f4abbadd6"
        fingerprint = "b1dcfff984f433943cb1ad449df00d5c94f85660d83808c6a895cf73e6c2f281"
        creation_date = "2026-05-22"
        last_modified = "2026-06-25"
        description = "Subject: BIOSTAR MICROTECH INT'L CORP"
        threat_name = "Windows.VulnDriver.Biostar"
        reference_sample = "86a8e0aa29a5b52c84921188cc1f0eca9a7904dcfe09544602933d8377720219"
        severity = 50
        arch_context = "x86"
        scan_context = "file"
        license = "Elastic License v2"
        os = "windows"
    strings:
        $subject_name = { 06 03 55 04 03 [2] 42 49 4F 53 54 41 52 20 4D 49 43 52 4F 54 45 43 48 20 49 4E 54 27 4C 20 43 4F 52 50 }
        $str1 = "BS_Flash64.pdb"
        $str2 = "\\Device\\BS_Flash64"
        $str3 = "\\DosDevices\\BS_Flash64"
    condition:
        int16(uint32(0x3C) + 0x5c) == 0x0001 and int16(uint32(0x3C) + 0x18) == 0x020b and $subject_name and $str1 and $str2 and $str3
}