Rubeus Kerberos Ticket Exports Through Winlogon Access
Description
The following analytic detects an uncommon process requesting full access rights to winlogon.exe, which may indicate Rubeus exporting Kerberos tickets from memory. It leverages Sysmon EventCode 10 and checks for full-access rights, specifically the value 0x1f3fff.
Query · spl
`sysmon`
EventCode=10
TargetImage="*:\\Windows\\system32\\winlogon.exe"
NOT SourceImage IN (
"C:\\Windows\\system32\\LogonUI.exe",
"C:\\Windows\\system32\\lsass.exe",
"C:\\Windows\\system32\\smss.exe",
"C:\\Windows\\system32\\svchost.exe",
"C:\\Windows\\system32\\wbem\\wmiprvse.exe"
)
```
Convert GrantedAccess from hexadecimal to decimal. 0x1f3fff is the legacy full-access mask observed for this activity.
```
| eval g_access_decimal = tonumber(replace(GrantedAccess,"0x",""),16)
| eval PROCESS_ALL_ACCESS_LEGACY = 2047999
| eval legacy_full_access_set = bit_and(g_access_decimal, PROCESS_ALL_ACCESS_LEGACY)
| where legacy_full_access_set == PROCESS_ALL_ACCESS_LEGACY
| stats count min(_time) as firstTime
max(_time) as lastTime
BY user_id dest
signature_id signature granted_access Opcode
SourceImage SourceProcessGUID SourceProcessId
TargetImage TargetProcessGUID TargetProcessId
CallTrace vendor_product
| eval CallTrace=split(CallTrace, "|")
| `security_content_ctime(firstTime)`
| `security_content_ctime(lastTime)`
| `rubeus_kerberos_ticket_exports_through_winlogon_access_filter`
Implementation guide
This search needs Sysmon Logs and a sysmon configuration, which includes EventCode 10. This search uses an input macro named sysmon. We strongly recommend that you specify your environment-specific configurations (index, source, sourcetype, etc.) for Windows Sysmon logs. Replace the macro definition with configurations for your Splunk environment.
Known false positives
- No false positives have been identified at this time.
Analyst notes
Known false positives: No false positives have been identified at this time.